Construct this pretty flower:

plot((1+cos(3*t)+sin(3*t)^2),t=0..2*Pi,coords=polar,axes=none,scaling=constrained,color=blue);

Construct the line segments joining (cos(t),0) with (0,sin(t)) as t ranges over [0,2Pi].

> m:=[[cos(t),0],[0,sin(t)]]:

> t:=n*Pi/50:

> plot([m$n=1..100],color=blue,axes=none,scaling=constrained);

Construct the velocity vector field along a constant motion around a circle.

> restart;

> x:=cos(t):

> y:=sin(t):

> m:=[[x,y],[x-y,y+x]]:

> t:=n*Pi/50:

> plot([m$n=1..100],color=blue,axes=none,scaling=constrained);

Construct this figure:

> restart;

> x:=cos(t):

> y:=sin(t):

> m:=[[x,y],[x+t*diff(x,t),y+t*diff(y,t)]]:

> t:=n*Pi/50:

> plot([m$n=1..100],color=blue,axes=none,scaling=constrained);

Construct the line segments joining [cos(t),sin(t)] with [cos(2t),sin(2t)] as t ranges over [0,2Pi].

> restart;

> x:=cos(t):

> y:=sin(t):

> m:=[[x,y],[cos(2*t),sin(2*t)]]:

> t:=n*Pi/50:

> plot([m$n=1..100],color=blue,axes=none,scaling=constrained);

Construct the line segments joining [cos(t),sin(t)] with [cos(3t),sin(3t)] as t ranges over [0,2Pi].

> restart;

> x:=cos(t):

> y:=sin(t):

> m:=[[x,y],[cos(3*t),sin(3*t)]]:

> t:=n*Pi/50:

> plot([m$n=1..100],color=blue,axes=none,scaling=constrained);

Construct this graph associated with the logistic equation x ' = ax(1-x)

> restart;

> a:=3.7:

> x:=0.643:

> y:=a*x*(1-x):

> m:=[]:

> for k to 100 do m:=[op(m),[x,x],[x,y]]:x:=y:y:=a*x*(1-x):od:

> plot(m,scaling=constrained,color=blue);

Draw 20 concentric circles as thus:

> restart;

> plot([[n*cos(t),n*sin(t),t=0..2*Pi]$n=1..20],color=blue,axes=none,scaling=constrained) ;

Construct the circles with center at (cos(t),sin(t)) passing through the point (1,0) with t ranging over [0,2Pi].

> restart;

> x:=cos(t*Pi/50):

> y:=sin(t*Pi/50):

> r:=((1-x)^2+y^2)^(1/2):

> m:=[x+r*cos(u),y+r*sin(u),u=0..2*Pi]:

> plot([m$t=1..100],color=blue,axes=none,scaling=constrained) ;

Construct the circles with center at (cos(t),sin(t)) and tangent to the y-axis with t ranging over [0,2Pi].

> restart;

> x:=cos(t*Pi/50):

> y:=sin(t*Pi/50):

> r:=abs(x):

> m:=[x+r*cos(u),y+r*sin(u),u=0..2*Pi]:

> plot([m$t=1..100],color=blue,axes=none,scaling=constrained) ;

Construct the circles with center at (cos(t),sin(t)) and and passing through (2cos(t)/3+cos(2t)/3,2sin(t)/3+sin(2t)/3) with t
ranging over [0,2Pi].

> x:=cos(t*Pi/50):

> y:=sin(t*Pi/50):

> x1:=2/3*x+1/3*cos(2*t*Pi/50):y1:=2/3*y-1/3*sin(2*t*Pi/50):

> r:=((x-x1)^2+(y-y1)^2)^(1/2):

> m:=[x+r*cos(u), y+r*sin(u), u=0..2*Pi]:

> plot([m$t=1..100],color=blue,axes=none,scaling=constrained);

Construct this figure:

> restart;

> x:=cos(t*Pi/50):

> y:=sin(t*Pi/50):

> x1:=3/4*x+1/4*cos(3*t*Pi/50):y1:=3/4*y-1/4*sin(3*t*Pi/50):

> r:=((x-x1)^2+(y-y1)^2)^(1/2):

> m:=[x+r*cos(u), y+r*sin(u), u=0..2*Pi]:

> plot([m$t=1..100],color=blue,axes=none,scaling=constrained);

Construct this pattern:

> restart;

> x:=cos(t*Pi/10):

> y:=sin(t*Pi/10):

> m:=[x+t*Pi*sin(u)/10, y+t*Pi*cos(u)/10, u=0..2*Pi]:

> plot([m$t=1..150],color=blue,axes=none,scaling=constrained);

Construct the reflections of a light ray inside a square:

> m:=2.7124:x:=0:y:=0:v:=[[x,y]]:

> for k to 100 do x1:=floor(x)+1:y1:=floor(y)+1:if (y1-y)>m*(x1-x) then x:=x1:y:=m*x else y:=y1:x:=y/m: fi:v:=[op(v),[1-abs(x-2*floor(x/2)-1),1-abs(m*x-2*floor(m*x/2)-1)]] od:

> plot(v,scaling=constrained,color=blue);

>